5
$\begingroup$

I'm trying to prepare some plots for publication using Mathematica 14.1. Although I give Mathematica the FontFamily->"Arial" option repeatedly in my code, it continues to use MathematicaSans and/or MathematicaSans-Bold fonts in the output. When I save the plots as PDF and then open in Adobe Illustrator, it gives a missing font error and prompts for replacement of these fonts. How can I force Mathematica to use Arial, Arial Bold, etc.? I'm not using any glyphs in my plots that aren't available in the Arial font family, so why is Mathematica picking a proprietary font?

Below is a pared-down example to demonstrate the issue (my actual plots source their data from an Excel spreadsheet instead of the Table commands in this toy example):

commonOptions[yaxisname_, aspectRatio_, imageSize_, imagePadding_, 
   axesFontSize_, legendFontSize_, legendPosition_, 
   dataLabels_] := {PlotRange -> {All, All}, 
   AspectRatio -> aspectRatio, ImageSize -> imageSize, 
   ImagePadding -> imagePadding, 
   BaseStyle -> {FontSize[10], FontFamily -> "Arial"}, 
   TicksStyle -> {FontFamily -> "Arial"}, 
   PlotStyle -> {{Black, 
      Directive[FontFamily -> "Arial"]}, {GrayLevel[0.7], Dashed, 
      Directive[FontFamily -> "Arial"]}}, 
   PlotLegends -> 
    Placed[LineLegend[
      Text@Style[#, Bold, legendFontSize, FontFamily -> "Arial"] & /@ 
       dataLabels, LegendFunction -> Framed], legendPosition], 
   Frame -> True, 
   LabelStyle -> 
    Directive[AbsoluteThickness[1.0], FontSize -> axesFontSize, 
     FontFamily -> "Arial"], AxesOrigin -> {0, 0}, 
   FrameLabel -> {Text@
      Style["Time (min)", Bold, axesFontSize, FontFamily -> "Arial"], 
     Text@Style[yaxisname, Bold, axesFontSize, 
       FontFamily -> "Arial"]}};

aspectRatio = 1;
imageSize = 300;
imagePadding = {{60, 20}, {55, 20}};
titleFontSize = 24;
axesFontSize = 18;
legendFontSize = 14;
firstPlot = 
  ListLinePlot[{Table[Sin[t], {t, 0, 2*Pi}], 
    Table[Sin[0.98*t] + 0.1, {t, 0, 2*Pi}]
    }, commonOptions["y-axis", aspectRatio, imageSize, imagePadding, 
    axesFontSize, 
    legendFontSize, {0.3, 0.25}, {"Data 1", "Data 2"}]];
secondPlot = 
  ListLinePlot[{Table[Cos[t], {t, 0, 2*Pi}], 
    Table[Cos[0.934*t] - 0.02, {t, 0, 2*Pi}]
    }, commonOptions["y-axis", aspectRatio, imageSize, imagePadding, 
    axesFontSize, legendFontSize, {0.6, 0.8}, {"Data 1", "Data 2"}]];
Labeled[GraphicsGrid[{{firstPlot, secondPlot}}, ImageSize -> 800, 
  Frame -> All, Alignment -> {Right, Bottom}, Spacings -> {20, 20}], 
 Style["Signals vs. Time", Bold, titleFontSize, 
  FontFamily -> "Arial"], Top, FrameMargins -> Tiny]

Output looks like this: enter image description here

If I right-click on this graphic, pick "Save Graphic As...", and save it as a PDF, when I open the PDF in Illustrator, I get the missing font problem.

Below is a screenshot of what I see when opening the PDF in Adobe Illustrator: This is what I see when opening the PDF in Adobe Illustrator

Improve this question
$\endgroup$
18
  • 6
    $\begingroup$ PlotStyle is used for styling the plot itself (i.e., color of curve or points, shape of points, dashing, etc.). I use BaseStyle -> {FontSize[10], FontFamily -> "Arial"} as one of the options in Plot. This tends to work for me. Then, instead of using "Save Graphic As...", I export the plot programatically with something like Export["MyPlot.pdf", plot], where plot is the plot. $\endgroup$ Commented Sep 20, 2024 at 18:31
  • 1
    $\begingroup$ @march I gave that a try, but it didn't fix the problem. Mathematica is still using MathematicaSans and MathematicaSans-Bold for dashes and parentheses, despite adding the BaseStyle option to the plot commands as you specified. $\endgroup$ Commented Sep 23, 2024 at 13:48
  • 1
    $\begingroup$ I've discovered a minimal example that shows the substitution is internal to Export[]. Maybe there's a workaround: ImportString[ ExportString[Style["-1.0", FontFamily -> "Arial"], "PDF"], "FormattedText"] // InputForm $\endgroup$ Commented Sep 24, 2024 at 15:14
  • 1
    $\begingroup$ @Domen I did use search. Putting PrivateFontOptions->{"OperatorSubstitution"->False} in the BaseStyle for the plot is among the many things that I have tried which did not work. $\endgroup$ Commented Sep 24, 2024 at 19:26
  • 2
    $\begingroup$ @Domen Perhaps you should pay more attention to the OP question then writing comments with "solutions" that do not work. The links are just workarounds for a bug. So it is not like there is no bug and people are using code incorrectly. There is definitely a bug. The workarounds work in some situations in other they do not work. It seems that no of the workarounds work for OP's case. And I think the main reason is Labeled which is wrapped around the plots. I was able to use the workarounds for a plain plot but once it is inside Labeled it will not work. i.e. the Mathematica fonts are added. $\endgroup$ Commented Sep 24, 2024 at 20:15

1 Answer 1

Reset to default
7
+50
$\begingroup$

The core issue is the "OperatorSubstitution" setting. But what's not obvious is that, if you set it from the outside, it can be overridden silently by internal styles. The override that will happen here has to do with the FormatType of the graphic. By default, FormatType->TraditionalForm, and that invokes the "TraditionalForm" style from the stylesheet which explicitly has "OperatorSubstitution"->True set. This is not a bug...all of these individual behaviors are designed that way for good reasons...but the interactions of these conditions is leading to results that weren't the easiest to predict and which, for your use case, are undesirable.

So, let's fix your example by making some changes to your commonOptions setting...

commonOptions[yaxisname_, aspectRatio_, imageSize_, imagePadding_, 
   axesFontSize_, legendFontSize_, legendPosition_, 
   dataLabels_] := {PlotRange -> {All, All}, 
   AspectRatio -> aspectRatio, ImageSize -> imageSize, 
   ImagePadding -> imagePadding, 
   BaseStyle -> {FontSize[10], FontFamily -> "Arial"}, 
   TicksStyle -> {FontFamily -> "Arial"}, 
   PlotStyle -> {{Black, 
      Directive[FontFamily -> "Arial"]}, {GrayLevel[0.7], Dashed, 
      Directive[FontFamily -> "Arial"]}}, 
   PlotLegends -> 
    Placed[LineLegend[
      Text@Style[#, Bold, legendFontSize, FontFamily -> "Arial"] & /@ 
       dataLabels, LegendFunction -> Framed], legendPosition], 
   Frame -> True, 
   LabelStyle -> 
    Directive[AbsoluteThickness[1.0], FontSize -> axesFontSize, 
     FontFamily -> "Arial", 
     PrivateFontOptions -> {"OperatorSubstitution" -> False} (*** added ***)],
   FormatType -> TextForm,  (*** added ***)
   AxesOrigin -> {0, 0}, 
   FrameLabel -> {Text@
      Style["Time (min)", Bold, axesFontSize, FontFamily -> "Arial"], 
     Text@Style[yaxisname, Bold, axesFontSize, 
       FontFamily -> "Arial"]}};

I've done two things here...

  • I've added the PrivateFontOptions setting to LabelStyle
  • I've added FormatType->TextForm as a top-level setting

That will entirely fix the graphics. I see that you're wrapping the graphics in Labeled. This style setting is internal to the graphics, and won't touch anything external. In your particular example, the Labeled doesn't introduce any Wolfram fonts, but it could. To account for that, you might just need to wrap a Style[] directive around the entire outer construct. E.g.,

Style[Labeled[...], PrivateFontOptions->{"OperatorFontSubstutition"->False}]
Improve this answer
$\endgroup$
2
  • $\begingroup$ (+1) Works on version 13.0.1. $\endgroup$ Commented Sep 25, 2024 at 15:05
  • $\begingroup$ That cures the problem with the font substitution on the minus signs in the ticks. The FormatType->TextForm caused the axes labels to display the word Text in the label, but that goes away if I just remove the Text@ in front of the Style options (it was getting wrapped with Text twice). I lose the Bold styling on the axes labels when the FormatType->TextForm is applied, but I can live with that. $\endgroup$ Commented Sep 25, 2024 at 15:24

Start asking to get answers

Find the answer to your question by asking.

Ask question

Explore related questions

See similar questions with these tags.