module "gitlab-runner" {
  source = "cattle-ops/gitlab-runner/aws"
  version = "9.2.2"

  environment = lower(var.environment)

  vpc_id = module.vpc.vpc_id
  subnet_id = element(module.vpc.private_subnets, 0)

  runner_instance = {
    name                = var.runner_name
    collect_autoscaling_metrics = ["GroupDesiredCapacity", "GroupInServiceCapacity"]

    ssm_access          = true
    docker_machine_type = "t3.xlarge"
  }

  runner_worker = {
    type = "docker+machine"
  }

  runner_networking = {
    allow_incoming_ping_security_group_ids = [data.aws_security_group.default.id]
  }

  runner_gitlab = {
    url                                           = var.gitlab_url
    preregistered_runner_token_ssm_parameter_name = "name"
  }

  runner_cloudwatch = {
    enable = true
    retention_days = 7
  }

  runner_worker_docker_machine_autoscaling_options = [
    # working 9 to 5 :)
    {
      periods = ["* * 0-9,17-23 * * mon-fri *", "* * * * * sat,sun *"]
      idle_count = 0
      idle_time  = 3600
      timezone   = var.timezone
    }
  ]

  # runner_worker_docker_services = [
  #   {
  #     name  = "docker:dind"
  #     alias = "docker"
  #     command = ["--registry-mirror", "https://mirror.gcr.io"]
  #     entrypoint = ["dockerd-entrypoint.sh"]
  #   }
  # ]

  runner_worker_docker_machine_instance = {
    monitoring = true
  }

  runner_worker_docker_machine_instance_spot = {
    max_price = "on-demand-price"
  }
}

module "vpc" {
  source  = "terraform-aws-modules/vpc/aws"
  version = ">= 5.16.0"

  name = "vpc-${var.runner_name}"
  cidr = "10.0.0.0/16"

  azs = [data.aws_availability_zones.available.names[0]]
  private_subnets = ["10.0.1.0/24"]
  public_subnets = ["10.0.101.0/24"]
  map_public_ip_on_launch = false

  enable_nat_gateway = true
  single_nat_gateway = true

  tags = {
    Environment = var.environment
  }
}

module "vpc_endpoints" {
  source  = "terraform-aws-modules/vpc/aws//modules/vpc-endpoints"
  version = ">= 5.16.0"

  vpc_id = module.vpc.vpc_id

  endpoints = {
    s3 = {
      service = "s3"
      tags = { Name = "s3-vpc-endpoint" }
    }
  }

  tags = {
    Environment = var.environment
  }
}