Add new indicators

Author: everget

src/movings/ehlers_deviation_scaled_moving_average.pine

@@ -4,25 +4,48 @@
 study("Ehlers Deviation-Scaled Moving Average", shorttitle="EDSMA", overlay=true)
 
 length = input(title="Length", type=integer, defval=40, minval=2)
+ssfLength = input(title="Super Smoother Filter Length", type=integer, defval=20, minval=1)
+numberOfPoles = input(title="Number of Poles", type=integer, defval=2, options=[2, 3])
 src = input(title="Source", type=source, defval=close)
 
 PI = 2 * asin(1)
 
-// Compute Super Smoother coefficients
-a1 = exp(-sqrt(2) * PI / (0.5 * length))
-b1 = 2 * a1 * cos(sqrt(2) * PI / (0.5 * length))
-c2 = b1
-c3 = -a1 * a1
-c1 = 1 - c2 - c3
+twoPoleSuperSmootherFilter(src, length) =>
+	arg = sqrt(2) * PI / length
+	a1 = exp(-arg)
+	b1 = 2 * a1 * cos(arg)
+	c2 = b1
+	c3 = -pow(a1, 2)
+	c1 = 1 - c2 - c3
+
+	ssf = 0.0
+	ssf := c1 * src + c2 * nz(ssf[1]) + c3 * nz(ssf[2])
+
+threePoleSuperSmootherFilter(src, length) =>
+	arg = PI / length
+	a1 = exp(-arg)
+	b1 = 2 * a1 * cos(1.738 * arg)
+	c1 = pow(a1, 2)
+
+	coef2 = b1 + c1
+	coef3 = -(c1 + b1 * c1)
+	coef4 = pow(c1, 2)
+	coef1 = 1 - coef2 - coef3 - coef4
+
+	ssf = 0.0
+	ssf := coef1 * src + coef2 * nz(ssf[1]) + coef3 * nz(ssf[2]) + coef4 * nz(ssf[3])
 
 zeros = src - nz(src[2])
 
 // Ehlers Super Smoother Filter
-ssf = 0.0
-ssf := c1 * (zeros + zeros[1]) / 2 + c2 * nz(ssf[1]) + c3 * nz(ssf[2])
+ssf = numberOfPoles == 2
+	 ? twoPoleSuperSmootherFilter((zeros + zeros[1]) / 2, ssfLength)
+	 : threePoleSuperSmootherFilter((zeros + zeros[1]) / 2, ssfLength)
 
 // Rescale filter in terms of Standard Deviations
-scaledFilter = ssf / stdev(ssf, length)
+scaledFilter = stdev(ssf, length) != 0
+	 ? ssf / stdev(ssf, length)
+	 : 0
 
 alpha = abs(scaledFilter) * 5 / length
 

src/movings/ehlers_leading_indicator.pine

@@ -0,0 +1,16 @@
+//@version=3
+// Copyright (c) 2018-present, Alex Orekhov (everget)
+// Ehlers Leading Indicator script may be freely distributed under the MIT license.
+study("Ehlers Leading Indicator", shorttitle="ELI", overlay=true)
+
+alpha1 = input(title="Alpha 1", type=float, step=0.1, defval=0.25)
+alpha2 = input(title="Alpha 2", type=float, step=0.1, defval=0.33)
+src = input(title="Source", type=source, defval=hl2)
+
+lead = 0.0
+lead := 2 * src + (alpha1 - 2) * nz(src[1]) + (1 - alpha1) * nz(lead[1])
+
+leadingIndicator = 0.0
+leadingIndicator := alpha2 * lead + (1 - alpha2) * nz(leadingIndicator[1])
+
+plot(leadingIndicator, title="ELI", linewidth=2, color=#741b47, transp=0)

src/movings/ehlers_mesa_adaptive_moving_averages.pine

@@ -0,0 +1,100 @@
+//@version=3
+// Copyright (c) 2018-present, Alex Orekhov (everget)
+// Ehlers MESA Adaptive Moving Averages (MAMA & FAMA) script may be freely distributed under the MIT license.
+study("Ehlers MESA Adaptive Moving Averages (MAMA & FAMA)", shorttitle="MESA", overlay=true)
+
+fastLimit = input(title="Fast Limit", type=float, defval=0.5)
+slowLimit = input(title="Slow Limit", type=float, defval=0.05)
+src = input(title="Source", type=source, defval=hl2)
+
+computeMESAComponent(src, mesaPeriodMult) =>
+	(0.962 * src + 0.5769 * nz(src[2]) - 0.5769 * nz(src[4]) - 0.0962 * nz(src[6])) * mesaPeriodMult
+
+computeAlpha(src, fastLimit, slowLimit) =>
+	mesaPeriod = 0.0
+	mesaPeriodMult = 0.075 * nz(mesaPeriod[1]) + 0.54
+
+	smooth = 0.0
+	smooth := (4 * src + 3 * nz(src[1]) + 2 * nz(src[2]) + nz(src[3])) / 10
+
+	detrender = 0.0
+	detrender := computeMESAComponent(smooth, mesaPeriodMult)
+
+	// Compute InPhase and Quadrature components
+	I1 = nz(detrender[3])
+	Q1 = computeMESAComponent(detrender, mesaPeriodMult)
+
+	// Advance the phase of I1 and Q1 by 90 degrees
+	jI = computeMESAComponent(I1, mesaPeriodMult)
+	jQ = computeMESAComponent(Q1, mesaPeriodMult)
+
+	I2 = 0.0
+	Q2 = 0.0
+
+	// Phasor addition for 3 bar averaging
+	I2 := I1 - jQ
+	Q2 := Q1 + jI
+
+	// Smooth the I and Q components before applying the discriminator
+	I2 := 0.2 * I2 + 0.8 * nz(I2[1])
+	Q2 := 0.2 * Q2 + 0.8 * nz(Q2[1])
+
+	// Homodyne Discriminator
+	Re = I2 * nz(I2[1]) + Q2 * nz(Q2[1])
+	Im = I2 * nz(Q2[1]) - Q2 * nz(I2[1])
+
+	Re := 0.2 * Re + 0.8 * nz(Re[1])
+	Im := 0.2 * Im + 0.8 * nz(Im[1])
+
+	if Re != 0 and Im != 0
+		mesaPeriod := 360 / atan(Im / Re)
+
+	if mesaPeriod > 1.5 * nz(mesaPeriod[1])
+		mesaPeriod := 1.5 * nz(mesaPeriod[1])
+
+	if mesaPeriod < 0.67 * nz(mesaPeriod[1])
+		mesaPeriod := 0.67 * nz(mesaPeriod[1])
+
+	if mesaPeriod < 6
+		mesaPeriod := 6
+
+	if mesaPeriod > 50
+		mesaPeriod := 50
+
+	mesaPeriod := 0.2 * mesaPeriod + 0.8 * nz(mesaPeriod[1])
+
+	smoothPeriod = 0.0
+	smoothPeriod := 0.33 * mesaPeriod + 0.67 * nz(smoothPeriod[1])
+
+	phase = 0.0
+
+	if I1 != 0
+		phase := atan(Q1 / I1)
+
+	deltaPhase = nz(phase[1]) - phase
+
+	if  deltaPhase < 1
+		deltaPhase := 1
+
+	alpha = fastLimit / deltaPhase
+
+	if  alpha < slowLimit
+		alpha := slowLimit
+
+	alpha
+
+mama(src, fastLimit, slowLimit) =>
+	alpha = computeAlpha(src, fastLimit, slowLimit)
+
+	mama = 0.0
+	mama := alpha * src + (1 - alpha) * nz(mama[1])
+
+fama(src, fastLimit, slowLimit) =>
+	alpha = computeAlpha(src, fastLimit, slowLimit)
+	mama = mama(src, fastLimit, slowLimit)
+
+	fama = 0.0
+	fama := (alpha / 2) * mama + (1 - alpha / 2) * nz(fama[1])
+
+plot(mama(src, fastLimit, slowLimit), title="MAMA", linewidth=2, color=#674ea7, transp=0)
+plot(fama(src, fastLimit, slowLimit), title="FAMA", linewidth=2, color=#f6b26b, transp=0)

src/movings/ehlers_super_smoother_filter.pine

@@ -0,0 +1,82 @@
+//@version=3
+// Copyright (c) 2018-present, Alex Orekhov (everget)
+// Ehlers Super Smoother Filter script may be freely distributed under the MIT license.
+study("Ehlers Super Smoother Filter", shorttitle="ESSF", overlay=true)
+
+length = input(title="Length", type=integer, defval=15, minval=1)
+numberOfPoles = input(title="Number of Poles", type=integer, defval=2, options=[2, 3])
+srcInput = input(title="Source", defval='cc2', options=['open', 'high', 'low', 'close', 'oo2', 'oh2', 'ol2', 'oc2', 'hh2', 'hl2', 'hc2', 'll2', 'lc2', 'cc2', 'hlc3', 'ohlc4', 'wc'])
+
+getSource(input) =>
+	src = 0.0
+
+	if input == 'open'
+		src := open
+	if input == 'high'
+		src := high
+	if input == 'low'
+		src := low
+	if input == 'close'
+		src := close
+	if input == 'oo2'
+		src := (open + nz(open[1])) / 2
+	if input == 'oh2'
+		src := (open + high) / 2
+	if input == 'ol2'
+		src := (open + low) / 2
+	if input == 'oc2'
+		src := (open + close) / 2
+	if input == 'hh2'
+		src := (high + nz(high[1])) / 2
+	if input == 'hl2' // Median Price
+		src := (high + low) / 2
+	if input == 'hc2'
+		src := (high + close) / 2
+	if input == 'll2'
+		src := (low + nz(low[1])) / 2
+	if input == 'lc2'
+		src := (low + close) / 2
+	if input == 'cc2'
+		src := (close + nz(close[1])) / 2
+	if input == 'hlc3' // Typical Price
+		src := (high + low + close) / 3
+	if input == 'ohlc4'
+		src := (open + high + low + close) / 4
+	if input == 'wc' // Weighted Close
+		src := (2 * close + high + low) / 4
+	src
+
+src = getSource(srcInput)
+
+PI = 2 * asin(1)
+
+twoPoleSuperSmootherFilter(src, length) =>
+	arg = sqrt(2) * PI / length
+	a1 = exp(-arg)
+	b1 = 2 * a1 * cos(arg)
+	c2 = b1
+	c3 = -pow(a1, 2)
+	c1 = 1 - c2 - c3
+
+	ssf = 0.0
+	ssf := c1 * src + c2 * nz(ssf[1]) + c3 * nz(ssf[2])
+
+threePoleSuperSmootherFilter(src, length) =>
+	arg = PI / length
+	a1 = exp(-arg)
+	b1 = 2 * a1 * cos(1.738 * arg)
+	c1 = pow(a1, 2)
+
+	coef2 = b1 + c1
+	coef3 = -(c1 + b1 * c1)
+	coef4 = pow(c1, 2)
+	coef1 = 1 - coef2 - coef3 - coef4
+
+	ssf = 0.0
+	ssf := coef1 * src + coef2 * nz(ssf[1]) + coef3 * nz(ssf[2]) + coef4 * nz(ssf[3])
+
+essf = numberOfPoles == 2
+	 ? twoPoleSuperSmootherFilter(src, length)
+	 : threePoleSuperSmootherFilter(src, length)
+
+plot(essf, title="ESSF", linewidth=2, color=#741b47, transp=0)

src/movings/spencer_15_point_moving_average.pine

@@ -0,0 +1,55 @@
+//@version=3
+// Copyright (c) 2018-present, Alex Orekhov (everget)
+// Spencer 15-Point Moving Average script may be freely distributed under the MIT license.
+study("Spencer 15-Point Moving Average", shorttitle="SpMA 15", overlay=true)
+
+src = input(title="Source", type=source, defval=close)
+
+getWeight(i) =>
+	weight = 0.0
+
+	if i == 0
+		weight := -3
+	if i == 1
+		weight := -6
+	if i == 2
+		weight := -5
+	if i == 3
+		weight := 3
+	if i == 4
+		weight := 21
+	if i == 5
+		weight := 46
+	if i == 6
+		weight := 67
+	if i == 7
+		weight := 74
+	if i == 8
+		weight := 67
+	if i == 9
+		weight := 46
+	if i == 10
+		weight := 21
+	if i == 11
+		weight := 3
+	if i == 12
+		weight := -5
+	if i == 13
+		weight := -6
+	if i == 14
+		weight := -3
+
+	weight
+
+spma15(src) =>
+	sum = 0.0
+	weightSum = 0.0
+
+	for i = 0 to 14
+		weight = getWeight(i)
+		sum := sum + nz(src[i]) * weight
+		weightSum := weightSum + weight
+
+	sum / weightSum
+
+plot(spma15(src), title="SpMA 15", linewidth=2, color=#741b47, transp=0)

src/movings/spencer_21_point_moving_average.pine

@@ -0,0 +1,67 @@
+//@version=3
+// Copyright (c) 2018-present, Alex Orekhov (everget)
+// Spencer 21-Point Moving Average script may be freely distributed under the MIT license.
+study("Spencer 21-Point Moving Average", shorttitle="SpMA 21", overlay=true)
+
+src = input(title="Source", type=source, defval=close)
+
+getWeight(i) =>
+	weight = 0.0
+
+	if i == 0
+		weight := -1
+	if i == 1
+		weight := -3
+	if i == 2
+		weight := -5
+	if i == 3
+		weight := -5
+	if i == 4
+		weight := -2
+	if i == 5
+		weight := 6
+	if i == 6
+		weight := 18
+	if i == 7
+		weight := 33
+	if i == 8
+		weight := 47
+	if i == 9
+		weight := 57
+	if i == 10
+		weight := 60
+	if i == 11
+		weight := 57
+	if i == 12
+		weight := 47
+	if i == 13
+		weight := 33
+	if i == 14
+		weight := 18
+	if i == 15
+		weight := 6
+	if i == 16
+		weight := -2
+	if i == 17
+		weight := -5
+	if i == 18
+		weight := -5
+	if i == 19
+		weight := -3
+	if i == 20
+		weight := -1
+
+	weight
+
+spma21(src) =>
+	sum = 0.0
+	weightSum = 0.0
+
+	for i = 0 to 20
+		weight = getWeight(i)
+		sum := sum + nz(src[i]) * weight
+		weightSum := weightSum + weight
+
+	sum / weightSum
+
+plot(spma21(src), title="SpMA 21", linewidth=2, color=#741b47, transp=0)